L’attività di progetto di questa mattina: progettazione di dispositivi elettronici che rispondono a diverse necessità per la salute umana: cura della persona, disabilità, sicurezza sul lavoro, strumenti medici/laboratorio, accessibilità dei luoghi pubblici, ecc…

Con mio piacere ne è nata un’intensa attività di ricerca che ha coinvolto l’intero gruppo classe. Molte le necessità e tra queste ne evidenzio uno, semplice, che riguarda la programmazione, che in più occasioni gli studenti affrontano durante le sperimentazioni e di cui mi sono reso conto di non avere documentato adeguatamente, ovvero: il plot di più funzioni su uno stesso piano cartesiano con Arduino.

Avevo mostrato in più occasioni come effettuare il plot di grandezze variabili nel tempo utilizzando la Serial Plotter dell’IDE di Arduino, uno degli ultimi articoli si riferisce alla realizzazione di uno strumento per la rilevazione di vibrazioni, un semplice sismografo realizzato con un sensore piezoelettrico.

Alcuni studenti questa mattina, si stavano cimentando nella progettazione di un guanto da utilizzare per la movimentazione di un braccio robot industriale della hyundai con l’obiettivo di simulare la movimentazione a distanza di sostanze chimiche pericolose. Nelle prime attività di ricerca si è manifestata la necessità di visualizzare su tre grafici diversi le componenti X, Y, Z dell’accelerazione fornite da un accelerometro connesso ad Arduino.

Come sicuramente saprete l’avvio della Serial Plotter avviene, così come per la Serial Monitor dal menù Tools. Ricordo che Serial Monitor e Serial Plotter non possono essere avviate contemporaneamente.

La Serial Plotter prende i valori che giungono dalla seriale (connessione USB) e li grafica su un piano cartesiano. I dati numerici vengono anche visualizzati nella parte in alto a sinistra della finestra della Serial Plotter.

I valori massimi e minimi rappresentati sull’asse Y vengono regolati automaticamente, mentre la dimensione dell’asse X è fissato a 500 punti e l’aggiornamento del grafico avviene ogni qual volta nel vostro sketch viene eseguita una Serial.println().

Ricordate inoltre di fissare il Baud Rate del Serial Plotter in modo che corrisponda a quello che avete indicato nel codice.

Per tracciare contemporaneamente forme d’onda è possibile agire in due modi:

inserendo uno spazio tra due istruzioni di stampa

Serial.print(temperatura);
Serial.print(" ");
Serial.println(umidita);

oppure inserendo una tabulazione tra due istruzioni di stampa

Serial.print(temperatura);
Serial.print("\t");
Serial.println(umidita);

In questo caso le due grandezze, temperatura e umidità, saranno rappresentate da due funzioni separate e tracciate contemporaneamente sullo stesso piano cartesiano.

A titolo di esempio consideriamo il mio post in cui mostravo come utilizzare un DHT11 e visualizzeremo sulla Serial Plotter le due grandezze fisiche temperatura ed umidità. Di seguito schema di collegamento, sketch e grafici.

// Prof. Maffucci Michele
// Visualizzazione della pressione e dell'umidità rilevata da un DHT11
// sulla Serial Plotter
// 16.09.2021

// Libreria DHT
#include "DHT.h"

// Pin digitale di arduino connesso al DHT
#define DHTPIN 2

// tipo del sensore: DHT 11
#define DHTTYPE DHT11

DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  dht.begin();
}

void loop() {
  // Attesa di 1 millisecondo prima di fornire la misura.
  delay(1);

  // Lettura dell'umidità
  float h = dht.readHumidity();
  // Lettura della temperatura in gradi Celsius
  float t = dht.readTemperature();

  // Verifica se le si presenta un errore di lettura (e riprova nuovamente)
  if (isnan(h) || isnan(t)) {
    Serial.println(F("Impossibile leggere dal sensore DHT!"));
    return;
  }

  // Stampa del valore dell'umidità
  Serial.print(h);
  Serial.print(' ');
  // Stampa del valore della temperatura
  Serial.println(t);
}

Il plot delle due grandezze è:

Per completezza realizziamo un semplice sketch che permette di rappresentare 3 funzioni sinusoidali sfasate di 90 gradi una rispetto all’altra con ampiezze diverse:

// Prof. Maffucci Michele
// Visualizzazione di tre funzioni siusoidali
// di ampiezza diversa e sfasate di 90 gradi
// 16.09.2021

void setup() {
  Serial.begin(9600);
}

void loop() {

  // M_PI è la macro definita nell'header math.h
  // che definisce il pi greco che ha il valore di:
  // 3.14159265358979323846
  for(int i = 0; i < 360; i += 2) {
    float ValoreY1 = 1 * sin(i * M_PI / 180);
    float ValoreY2 = 2 * sin((i + 90)* M_PI / 180);
    float ValoreY3 = 4 * sin((i + 180)* M_PI / 180);

    Serial.print(ValoreY1);
    Serial.print(' ');         // deve essere stampato spazio ' ' o  tab '\t' tra due valori.
    Serial.print(ValoreY2);
    Serial.print(' ');         // deve essere stampato spazio ' ' o  tab '\t' tra due valori.
    Serial.println(ValoreY3);  // l'ultimo valore deve avere un ritorno a capo

    delay(1);
  }
}

Buon Coding a tutti 🙂