Archivi tag: NEMA 17

Controllare un motore passo passo unipolari con Arduino

In queste settimane i miei studenti stanno svolgendo una serie di esercitazioni in cui è necessario controllare la rotazione di un motore passo passo (stepper). L’obiettivo delle esercitazioni è quello di simulare il sistema di controllo di un forno a microonde e lo stepper viene utilizzato per la rotazione del piatto.

In un precedente articolo ho dettagliato il principio di funzionamento di questa tipologia di motori, in questo post ne riassumo le principali caratteristiche e condivido alcuni esempi che sono di base per la realizzazione delle sperimentazioni svolte per il laboratorio di TPSEE e Sistemi.

Richiami

Il vantaggio principale rispetto ad un motore brushed (a spazzola) in corrente continua e di un servomotore e che l’albero di rotazione di uno stepper può essere posizionati con precisione, spostandolo in avanti o all’indietro di un “passo” alla volta, ma possono anche ruotare continuamente.
In questa lezione verrà mostrato come controllare un motore passo-passo utilizzando Arduino ed un ponte H L293D, lo stesso utilizzato per controllare un motore a spazzola come quelli utilizzati in molti dei kit robotici che trovate sia questo sito.

Caratteristiche principali di uno stepper

La differenza sostanziale da un motore brushed in corrente continua risiede nel fatto che un motore passo passo mantiene la velocità di rotazione costante anche con un carico applicato, ovvero se sottoposti a sforzo mantengono velocità costante. Questa caratteristica consente di evitare sistemi di controreazione, utilizzando ad esempio degli encoder, per il mantenimento costante della velocità.
i motori passo passo erogano coppie elevate anche a basso numero di giri.
accelerazioni e frenate repentine
mantenimento del carico fermo e senza vibrazioni

Difetti

E’ necessario utilizzare un circuito elettrico di pilotaggio
rendimento energetico basso
velocità di rotazione ridotta
costo di acquisto elevato

Per le caratteristiche tecniche, il principio di funzionamento e le modalità di connessione vi rimando all’articolo: Controllo di un motore passo-passo bipolare NEMA17 con Driver L298N

Negli sketch di esempio che troverete in questo articolo prendo in considerazione 3 tipologie di stepper: i piccoli stepper dei CD-ROM e dei DVD dei computer, 28BYJ-48 comuni in molti kit Arduino, e i NEMA 17.

Negli sketch di esempio che troverete in questo articolo prendo in considerazione 3 tipologie di stepper: i micro stepper dei CD-ROM e dei DVD dei computer, i 28BYJ-48 comuni in molti kit Arduino, e i nema 17.

Negli sketch troverete alcune parti commentate, togliendo il commento ad alcune linee di codice, potrete impostare il funzionamento per una delle tre tipologie di stepper.

Una delle attività svolte nello scorso anno scolastico dai miei allievi è stato il recupero di tutti gli stepper dei vecchi pc alienati della scuola, ciò mi ha permesso di realizzare velocemente tutta una serie di esercitazioni sull’uso dei motori passo passo.

Gli tutti gli stepper recuperati sono stati posti su supporti stampati in 3D e fissati su basette di compensato. L’utilizzo degli stepper dei CD-ROM consente inoltre di realizzare attività di progetto interessanti, come ad esempio piccoli plotter oppure dei laser engraver.

Raccomandazioni per i miei studenti

Punto 1

Ricordate di individuare le bobine di un motore passo passo, l’operazione è un po’ difficoltosa per i passo passo dei CD-ROM che in genere non sono identificati da colori o dalla posizione.
Prima di collegare il motore alla scheda motori è necessario individuare i cavi A+, A-, B+ e B- sul motore. La maniera migliore è quella di consultare la scheda tecnica del motore in cui vi è una corrispondenza tra colore filo e cavo. In alternativa potete utilizzare un multimetro in modalità ohmmetro e misurare la resistenza tra le coppie dei cavi, quando misurerete un valore tra i 2 e i 4 ohm tra due terminali avrete individuato una delle bobine.

Punto 2

Sempre per i passo passo dei CD-ROM i fili di collegamento sono saldati al motore ed il punto di saldatura è molto piccolo, inoltre i fili di collegamento sono sottili è molto alto il rischio di romperli. Per evitare ciò ho utilizzato una strategia semplice ed economica, un ponte con un mammut su cui collego poi i fili che vanno ad essere collegati alla breadboard, così come rappresentato nell’immagine.

Punto 3

La spiegazione del funzionamento di ogni sketch è dettagliata con commenti nello sketch e tutti gli esempi sono da considerare come base di partenza per le esercitazioni svolte in presenza.

Esempio 1

Controllo rotazione stepper da Serial Monitor mediante tastiera. Valori positivi rotazione oraria, valori negativi rotazione antioraria

// Prof. Michele Maffucci
// 20.10.2020

// Controllo rotazione stepper mediante tastiera
// valori positi rotazione oraria
// valori negativi rotazione antioraria

#include <Stepper.h>

int in1Pin = 12;
int in2Pin = 11;
int in3Pin = 10;
int in4Pin = 9;

/*
in1 L293D - pin 12 Arduino
in1 L293D - pin 11 Arduino
in1 L293D - pin 10 Arduino
in1 L293D - pin 9 Arduino
*/

// 200 per stepper 17PM-M041-P1 - 12 V - 1,8 gradi per step

// 200 per microstepper CDROM - 5 V - 1,8 gradi per step
// per evitare che slitti sul supporto impostare 170 come limite massimo

// 512 per stepper 28BY J-48 - 5 V - 5,525 gradi per step
// per questo stepper il valore passato non e' step/giro 
// per un giro completo 2048 step. 512 equivale ad 1/4 di giro 

// inizializzazione della libreria Stepper

const int stepPerGiro = 200;  // adattare al passo di rotazione del vostro stepper

Stepper myStepper(stepPerGiro, in1Pin, in2Pin, in3Pin, in4Pin);  
 
void setup()
{
  pinMode(in1Pin, OUTPUT);
  pinMode(in2Pin, OUTPUT);
  pinMode(in3Pin, OUTPUT);
  pinMode(in4Pin, OUTPUT);
  
  Serial.begin(9600);
  
  // rotazioni per minuto, funzione dello stepper a disposizione
  // e' un valore positivo.
  // la funzione setSpeed non fa ruotare il stepper, imposta solamente la velocita'
  myStepper.setSpeed(70);    // imposta la velocita' di rotazione a 20 rpm:
}

void loop()
{
  if (Serial.available())
  {
    int steps = Serial.parseInt();
    
    // valori positivi fanno girare il mySteppere in senso orario
    // valori negativi fanno girare il mySteppere in senso antioraio
    myStepper.step(steps);
  }
}

Esercizio 2

Realizzare uno sketch che permetta di contare il numero di passi di rotazione fissato il numero di step per passo. Si evidenzi il raggiungimento di un passo con l’accensione di un LED.

Si visualizzi sulla serial monitor il messaggio:

“PASSO” – passo rotazione modulo “MODULO” passo: “CONTATORE STEP”

sono variabili:

“PASSO”,
“MODULO”
“CONTATORE STEP”

Nell’esempio:

PASSO: numero sequenziale
MODUOLO: step per passo
CONTATORE STEP: modulo del passo

// Prof. Michele Maffucci
// 20.10.2020

// contatore passi
// il programma puo' pilotare stepper unipolari o bipolari
// il numero di passi fissato nella variabile moduloStep
// ad ogni passo viene rilevato anche da un LED

// 200 per stepper 17PM-M041-P1 - 12 V - 1,8 gradi per step

// 200 per microstepper CDROM - 5 V - 1,8 gradi per step
// per evitare che slitti sul supporto impostare 170 come limite massimo

// 512 per stepper 28BY J-48 - 5 V - 5,525 gradi per step
// per questo stepper il valore passato non e' step/giro 
// per un giro completo 2048 step. 512 equivale ad 1/4 di giro 


#include <Stepper.h>

const int stepPerGiro = 170;  // adattare al passo di rotazione del vostro stepper

// inizializzazione della libreria Stepper
Stepper myStepper(stepPerGiro, 12, 11, 10, 9);

int contatorePassi = 0;         // numero di step raggiunto
int moduloStep = 20;            // modulo rotazione stepper da 1 a numero massimo di passi
                                // se moduloStep = 1 diventa un contatore di step
int conta = 0;                  // conteggio fase

int ledPin = 7;                 // led rilevamento fase

void setup() {
  // inizializzazione porta seriale
  Serial.begin(9600);
  // imposta la velocita' di rotazione a 20 rpm
  myStepper.setSpeed(20);
  
  pinMode(ledPin, OUTPUT);
}

void loop() {
  // passi di rotazione
  myStepper.step(moduloStep);
  Serial.print(conta);
  Serial.print(" - ");
  Serial.print("passo rotazione modulo ");
  Serial.print(moduloStep);
  Serial.print(" ");
  Serial.print("passo: ");
  Serial.println(contatorePassi);
  digitalWrite(ledPin, HIGH);
  conta++;
  contatorePassi=contatorePassi+moduloStep;
  if (contatorePassi &amp;gt; stepPerGiro){
    contatorePassi = 0;
    conta = 0;
  }
  delay(500);
  digitalWrite(ledPin, LOW);
}

Variante per stepper 28BY J 48

// Prof. Michele Maffucci
// 20.10.2020

// contatore passi
// il programma puo' pilotare stepper unipolari o bipolari
// il numero di passi fissato nella variabile moduloStep
// ad ogni passo viene rilevato anche da un LED

// in questo sketch si puo' effettuare le dovute correzioni per lo stepper
// 28BY J-48

// 200 per stepper 17PM-M041-P1 - 12 V - 1,8 gradi per step

// 200 per microstepper CDROM - 5 V - 1,8 gradi per step
// per evitare che slitti sul supporto impostare 170 come limite massimo

// 512 per stepper 28BY J-48 - 5 V - 5,525 gradi per step
// per questo stepper il valore passato non e' step/giro
// per un giro completo 2048 step. 512 equivale ad 1/4 di giro


#include <Stepper.h>

const int stepPerGiro = 512;  // adattare al passo di rotazione del vostro stepper

const int BY = 1;             // 1 uso di BY - 0 uso di altro motore passo passo

// inizializzazione della libreria Stepper
Stepper myStepper(stepPerGiro, 11, 9, 10, 8);

int contatorePassi = 0;         // numero di step raggiunto
int moduloStep = 512;           // modulo rotazione stepper da 1 a numero massimo di passi
// se moduloStep = 1 diventa un contatore di step
int conta = 0;                  // conteggio fase

int ledPin = 13;                 // led rilevamento fase

void setup() {
  // inizializzazione porta seriale
  Serial.begin(9600);
  // imposta la velocita' di rotazione a 20 rpm
  myStepper.setSpeed(70);

  pinMode(ledPin, OUTPUT);
}

void loop() {
  // passi di rotazione
  myStepper.step(moduloStep);
  Serial.print(conta);
  Serial.print(" - ");
  Serial.print("passo rotazione ");
  Serial.print("modulo ");
  Serial.print(moduloStep);
  Serial.print(" ");
  Serial.print("passo: ");
  Serial.println(contatorePassi);
  digitalWrite(ledPin, HIGH);
  contatore();
  delay(500);
  digitalWrite(ledPin, LOW);
}

// funzione che conta i passi in funzione dello stepper utilizzato
void contatore() {
  conta++;
  contatorePassi = contatorePassi + moduloStep;
  switch (BY) {
    case 0:
      if (contatorePassi &amp;gt; stepPerGiro) {
        contatorePassi = 0;
        conta = 0;
      }
      break;
    case 1:
      if (contatorePassi &amp;gt; stepPerGiro * 4) {
        contatorePassi = 0;
        conta = 0;
      }
      break;
  }
}

Esempio 3

Realizzare uno sketch che permetta di far compiere in modo continuo un giro completo in senso orario ed uno in senso antiorario.

Svolgere l’esercizio sia con lo stepper 28BY J-48 che con il microstepper del CDROM

Noterete che per il microstepper del CDROM il carrello giunto alla fine slitta, in quanto 200 step per rotazione sono troppi. Valutare (in modo empirico) quanti stemp sono necessari affinche il carrello non slitti e modificare lo sketch di conseguenza.

Variante 1

Fare in modo che al completamento di un giro venga acceso un diodo LED

Variante 2

Utilizzando il microstepper fare in modo che il verso di spostamento della slitta sia segnalato da due LED ed i LED siano accesi in modo alternato in funzione del verso di scorrimento della slitta

- Direzione 1 – LED rosso acceso, LED verde spendo
- Direzione 2 – LED rosso spento, LED verde acceso

// Prof. Michele Maffucci
// 20.10.2020

// rotazione oraria e antioraria sequenziale

/*
in1 L293D - pin 12 Arduino
in1 L293D - pin 11 Arduino
in1 L293D - pin 10 Arduino
in1 L293D - pin 9 Arduino
*/

// 200 per stepper 17PM-M041-P1 - 12 V - 1,8 gradi per step

// 200 per microstepper CDROM - 5 V - 1,8 gradi per step
// per evitare che slitti sul supporto impostare 170 come limite massimo

// 512 per stepper 28BY J-48 - 5 V - 5,525 gradi per step
// per questo stepper il valore passato non e' step/giro 
// per un giro completo 2048 step. 512 equivale ad 1/4 di giro

#include <Stepper.h>

const int stepPerGiro = 170;  // adattare al passo di rotazione del vostro stepper

// inizializzazione della libreria Stepper
Stepper myStepper(stepPerGiro, 12, 11, 10, 9);

void setup() {
  // inizializzazione porta seriale
  Serial.begin(9600);
  // imposta la velocita' di rotazione a 60 rpm:
  myStepper.setSpeed(60);
}

void loop() {
  // un giro completo in senso orario
  Serial.println("antiorario");
  myStepper.step(stepPerGiro);
  delay(500);
  
  // un giro completo in senso antiorario
  Serial.println("orario");
  myStepper.step(-stepPerGiro);
  delay(500);
}

Esempio 4

Realizzare uno sketch che permetta di far cambiare il senso di rotazione alla pressione di un pulsante.
Rilevare la pressione del pulsante con l’accensione del LED collegato al pin 13.
Si colleghi il pulsante al pin 2 di Arduino, secondo quanto specificato nello schema di seguito. Utilizzare per questo esercizio il microstepper.

// Prof. Michele Maffucci
// 20.10.2020

// Cambio direzione rotazione alla pressione di un pulsante

// il programma puo' pilotare stepper unipolari o bipolari
// il numero di passi  fissato nella variabile moduloStep
// ad ogni passo viene rilevato anche da un LED

// 200 per stepper 17PM-M041-P1 - 12 V - 1,8 gradi per step

// 200 per microstepper CDROM - 5 V - 1,8 gradi per step
// per evitare che slitti sul supporto impostare 170 come limite massimo

// 512 per stepper 28BY J-48 - 5 V - 5,525 gradi per step
// per questo stepper il valore passato non e' step/giro
// per un giro completo 2048 step. 512 equivale ad 1/4 di giro


#include <Stepper.h>

const int stepPerGiro = 200;  // adattare al passo di rotazione del vostro stepper

// inizializzazione della libreria Stepper
Stepper myStepper(stepPerGiro, 12, 11, 10, 9);

int contatorePassi = 0;         // numero di step raggiunto
int moduloStep = 10;            // modulo rotazione stepper da 1 a numero massimo di passi
                                // se moduloStep = 1 diventa un contatore di step

int moduloStepCorrente;         // variabile in cui memorizzare la direzione di rotazione corrente
                                // alla pressione del pulsante


const int pinPulsante = 2;      // pin a cui e' collegato il pulsante
const int ledPin = 13;          // pin a cui e' collegato il LED

int statoPulsante = 0;           // stato corrente del pulsante


void setup() {
  
  // inizializzazione pin a cui e' collegato il pulsante
  pinMode(pinPulsante, INPUT);
  
  // inizializzazione pin a cui e' collegato il LED
  pinMode(ledPin, OUTPUT);

  // imposta la velocita' di rotazione a 20 rpm
  myStepper.setSpeed(20);
}

void loop() {

  statoPulsante = digitalRead(pinPulsante);
  if (statoPulsante == HIGH) {
    digitalWrite(ledPin, HIGH);
    moduloStepCorrente = -moduloStep;
    myStepper.step(moduloStepCorrente);
  }
  else {
    digitalWrite(ledPin, LOW);
    myStepper.step(moduloStep);
  }
}

Controllo di un motore passo-passo bipolare NEMA17 con Driver L298N

Lascia una risposta

I motori “passo-passo” o “stepper” sono motori elettrici sincroni il cui avanzamento avviene a passo singolo corrispondente ad uno specifico angolo di rotazione, pertanto è possibile farli ruotare a piacimento di un angolo preciso. Uno stepper è in grado di mantenere con precisione velocità di rotazione e posizione senza la necessitò di utilizzo di trasduttori di feedback come dinamo tachimetriche o encoder.
I motori passo-passo sono ampiamente utilizzati nell’ambito dell’automazione industriale: robotica, stampanti, scanner, o per esempio come stanno facendo alcuni miei allievi, per regolare l’inclinazione di un pannello solare per realizzare un inseguitore solare.

Rispetto ad altre tipologie di motori elettrici il motore passo-passo non modifica la velocità di rotazione in funzione della coppia a cui è sottoposto l’albero rotante, la mantiene costante e nel caso in cui la coppia aumenti il motore si ferma.

I motori stepper per essere pilotati richiedono una sequenza di impulsi generati da appositi circuiti elettronici di controllo.

In laboratorio vedremo come controllare il movimento di un motore passo-passo bipolare con Arduino mediante l’uso di un Motor Driver L298N. Su questo sito ho dettagliato l’uso di questa scheda per controllare motori in CC per robot didattici, però con questo tutorial voglio indicare ai miei studenti come effettuare il controllo di un motore passo passo NEMA17 che dovranno utilizzare nelle prossime esperienze di laboratorio.

Richiami teorici

Lo stepper motor o motore passo-passo è definito anche come “trasduttore elettromeccanico” in quanto converte impulsi elettrici di comando in passi elementari (step) di ampiezza angolare fissata in funzione del tipo di motore.

Questo tipo di motore elettrico per poter funzionare deve essere collegato ad un circuito di alimentazione specifico e ad un sistema di controllo elettronico in grado di governare l’angolo e la velocità di rotazione.
Come per tutti i motori elettrici anche il motore passo-passo è costituito da una parte fissa detta statore ed una parte mobile detta rotore su cui è connesso un albero di rotazione dotato di cuscinetti:

Nello statore sono disposti gli avvolgimenti di rame, costituiti da bobine di rame smaltato (isolato), mentre il rotore è costituito da materiale magnetico.

Esistono tre tipi di motori passo passo:

a magnete permanente (PM)
a riluttanza variabile (VR)ibrido (HY)

Gli avvolgimenti dello statore sono collegati in modo da realizzare un sistema bifase, ma esistono anche sistemi trifase e polifase ma sono più rari.

I motori passo-passo si suddividono a loro volta in due famiglie:

motori bipolari (la corrente negli avvolgimenti statorici scorre nei due versi)
motori unipolari (la corrente negli avvolgimenti statorici scorre in un solo verso)

In questa guida prenderà in considerazione solamente i motori a magneti permanenti (PM) e di questi considereremo solamente i motori passo-passo bipolari. La spiegazione teorica e l’utilizzo delle altre tipologie di motori sarà argomento di successive lezioni.

Motore a magnete permanente – motore passo-passo bipolare

Il principio di funzionamento di questa tipologia di motori è basato sull’attrazione di due poli magnetici che presentano polarità differenti. Un polo è costituito da un magnete permanete (calamita) mentre l’altro è il polo di un elettromagnete il cui magnetismo è generato da una corrente che fluisce in spire avvolte su un materiale ferromagnetico.

Si ricorda che facendo scorrere una corrente su una bobina avvolta su un nucleo di ferro viene generato un campo magnetico che presenterà una polarità Nord-Sud secondo la “regola della mano destra”:

immaginiamo di impugnare l’avvolgimento con la mano destra in modo che le dita indichino il verso di percorrenza della corrente, il pollice indicherà la direzione del vettore campo elettromagnetico e la punta del pollice indica il verso del vettore individuando il Nord magnetico:

Per far muovere il rotore dovremo quindi modificare il verso di percorrenza della corrente nelle bobine dello statore in modo che la forza di attrazione Nord-Sud tra i poli dello statore e del rotore generi il moto rotatorio.

Nello statore sono presenti due magneti disposti in maniera ortogonale uno rispetto all’altro su cui sono avvolte due bobina i cui terminali sono nominati: A+ e A-, B+ e B- così sono indicati nelle tabelle tecniche di questi dispositivi (i segni + e – a fianco alle lettere A e B non sono da confondere con la polarità), mentre il rotore è costituito da un magnete permanente costituito quindi da un polo Nord e un polo Sud.

Movimento del rotore

Facendo circolare una corrente continua nell’avvolgimento statorico A+ e A- viene generato un campo magnetico che porterà il rotore a ruotare e a bloccarsi nella posizione in cui le polarità magnetiche saranno opposte, così come indicato nel disegno che segue:

Togliendo alimentazione all’avvolgimento statorico A+ A- e alimentando l’avvolgimento statorico B+ B- si avrà una configurazione differente dei magneti statorici ed una conseguente rotazione di 90° del rotore in senso antiorario, come indicato nel disegno che segue:

Togliendo alimentazione all’avvolgimento statorico B+ B- e alimentando in senso opposto (polarità inversa) l’avvolgimento statorico A+ A- si invertiranno le polarità del campo magnetico ed una rotazione di 90° in senso antiorario del rotore così come indicato nel disegno che segue:

Da ciò si comprende che invertendo il verso di percorrenza della corrente prima prima in un avvolgimento statorico e poi nell’altro si otterrà ogni volta una rotazione di 90° del rotore.
L’alimentazione di una fase alla volta (di un avvolgimento statorico alla volta) è detto a “full step”, cioè passo intero.

La sequenza completa di rotazione è costituita da 4 passi (o 4 fasi) e quindi per ottenere una rotazione continua del rotore bisognerà realizzare la seguente sequenza di alimentazione:

La sequenza di movimento, secondo la tabella sopra indicata, sarà quella dell’immagine che segue dove per semplicità di esposizione è stato semplificato il disegno del motore:

Per invertire il senso di rotazione degli elettromagneti sarà sufficiente quindi invertire la sequenza con cui vengono alimentate le bobine statoriche.

Il movimento del motore può avvenire anche alimentando contemporaneamente entrambe le bobine statoriche, in questo modo il rotore si disporrà a 45° rispetto alla posizione precedente. La tabella delle singole fasi diventa:

la posizione del rotore sarà quella descritta dai disegni che seguono:

Controllo

I fili che costituisco i due poli sono distinti da colori diversi e il controllo del motore passo-passo deve essere effettuato da un driver bipolare, nel nostro caso un L298N.

La sequenza di eccitazione, sarà realizzata da un microcontrollore, nel nostro caso Arduino ed in una successivamente lezione vedremo come controllare uno stepper mediante PLC Siemens 1200 con un’altro tipo di driver.

Il driver bipolare, può essere paragonato in estrema sintesi a 8 interruttori, 4 interruttori per ogni bobina statorica

Elettronicamente il driver bipolare è costituito da un circuito elettronico a doppio ponte H, il nostro L298N, che consente di invertire il senso della corrente nelle bobine statoriche. Gli interruttori del circuito precedente vengono realizzati con transitor mosfet o bjt. Comandando la polarizzazione di coppie di transitor per ogni ponte H sarà possibile alimentare le bobine con polarità diverse.

Nell’esempio che segue viene preso in considerazione un solo ponte H.

Nel circuito sono presenti 4 transitor due NPN (Tr2 e Tr3) e due PNP (Tr1 e Tr4), collegati come indicato nel disegno che segue:

Mediante l’utilizzo di due output digitali di un microcontrollore invieremo sui pin IN1 e IN2 valori HIGH e LOW (tensioni di 5V e 0V) in modo da controllare la polarizzazione dei transitor e il conseguente verso di percorrenza della corrente che circola nella bobina statorica del motore.

Quando nel punto IN1 si ha un valore HIGH e su IN2 un valore LOW, andranno in conduzionei transistor Tr4 e Tr2 provocando la rotazione in un senso del motore

quando nel punto IN1 il segnale è LOW e su IN2 il segnale è HIGH i transistor che andranno in conduzione saranno il Tr1 e il Tr3, provocando la rotazione nel senso opposto al passo precedente:

La modalità di collegamento del circuito impedisce di alimentare contemporaneamente la coppia di transitor evitando così cortocircuiti.
I quattro diodi sono detti diodi di ricircolo ed il loro scopo è quello di proteggere i transistor dalla sovratensione generata dalla bobina statorica (induttanze) nel momento dell’apertura del circuito, infatti quando i transitor passano dalla condizione di conduzione a quella di interdizione (si apre l’interruttore) la corrente circolante dovrebbe andare istantaneamente a zero, ma l’induttore (la bobina statorica del motore) tende ad impedire questa brusca variazione, la tensione sul collettore del transitor tende ad aumentare a valori molto elevati.

Se immaginate il transitor in interdizione come ad un interruttore aperto, che quindi assume una resistenza elevatissima, l’induttore si comporterà per un breve istante come un generatore di tensione cercando di far passare in questa resistenza elevatissima la stessa corrente che era presente quando il bjt si comportava come interruttore chiuso, ma per la legge di ohm (V = RxI) la tensione sul collettore del bjt raggiunge valori molto alti, superiori alla tensione di alimentazione danneggiando il bjt.
Per evitare la distruzione del bjt viene inserito un diodo con catodo rivolto verso il positivo dell’alimentazione.

Durante la conduzione del transistor, il diodo non sarà polarizzato direttamente, mentre quando non sarà polarizzato (interruttore aperto) la corrente non passerà più attraverso il transistor, ma attraverso il diodo polarizzato direttamente.

Realizzazione del circuito

Il NEMA 17 richiede un’alimentazione tipica di 12V. La rotazione completa di 360° del rotore si ottiene facendo compiere 200 passi al motore. Ogni passo corrisponderà ad un angolo di 1,8°. La velocità massima che questo tipo di motore può raggiungere è di 60 RPM (dall’inglese revolutions per minute in italiano rotazioni per minuto giri/min).

Prima di collegare il motore alla scheda motori è necessario individuare i cavi A+, A-, B+ e B- sul motore. La maniera migliore è quella di consultare la scheda tecnica del motore in cui vi è una corrispondenza tra colore filo e cavo. In alternativa potete utilizzare un multimetro in modalità ohmmetro e misurare la resistenza tra le coppie dei cavi, quando misurerete un valore tra i 2 e i 4 ohm tra due terminali avrete individuato una delle bobine.

Collegare l’alimentazione esterna a 12V al terminale VCC e mantenere posizionare i jumper (i ponticelli) ENA ed ENB come indicato nell’immagine che segue in modo che il motore passo passo sia sempre abilitato al funzionamento.

Effettuare il collegamento dei pin di ingresso (IN1, IN2, IN3 e IN4) del modulo L298N a quattro pin di uscita digitale Arduino, nell’esempio sono stati utilizzati i pin: 8, 9, 10 e 11.

Collegare i fili A +, A-, B + e B- dal motore passo-passo al modulo come mostrato nell’immagine che segue.

Lo sketch indicato di seguito, che potrete utilizzare come base di partenza per le vostre sperimentazioni, permetterà di controllare il motore passo-passo facendogli compiere ripetutamente un giro in senso orario ed uno in senso antiorario.

// Inclusione della libreria stopper
#include <Stepper.h>

// Numero di step (passi) per effettuare una rotazione completa
const int stepPerRotazione = 200;

// Creazione dell’istanza dello Stepper
Stepper mioStepper(stepPerRotazione, 8, 9, 10, 11);

void setup()
{
    // impostazione della rotazione a 60 rpm:
    mioStepper.setSpeed(60);
    // inizializzazione della porta seriale:
    Serial.begin(9600);
}

void loop() 
{
    // una rotazione in una direzione
    Serial.println("Rotazione oraria");
    mioStepper.step(stepPerRotazione);
    delay(500);

    // una rotazione in una direzione
    Serial.println("Rotazione antioraria");
    mioStepper.step(-stepPerRotazione);
    delay(500);
}

Questo sketch include la libreria Stepper https://www.arduino.cc/en/Reference/Stepper.
La libreria avrà il compito di sequenziare gli impulsi verranno inviati al motore stepper.

// Inclusione della libreria stopper
#include <Stepper.h>

Definizione della variabile stepPerRotazione che stabilisce il numero di passi per un’intera rivoluzione, in questo caso 200 che corrispondono a 1,8 gradi per passo.

// Numero di step (passi) per effettuare una rotazione completa
const int stepPerRotazione = 200;

Creazione di un’istanza della libreria stepper. La creazione dell’istanza prevede l’indicazione del numero di step per rivoluzione e l’indicazione dei 4 pin digitali di Arduino a cui dovranno essere collegati i pin IN1, IN2, IN3, IN4 della scheda L298N.

// Creazione dell’istanza dello Stepper
Stepper mioStepper(stepPerRotazione, 8, 9, 10, 11);

Nel setup:

impostiamo la velocità del motore passo-passo invocando la funzione setSpeed()
impostiamo la velocità di comunicazione della Serial Monitor

void setup()
{
    // impostazione della rotazione a 60 rpm:
    mioStepper.setSpeed(60);
    // inizializzazione della porta seriale:
    Serial.begin(9600);
}

Nel loop() invochiamo la funzione step() che permette di stabilire il numero di passi, valori negativi consentono di invertire il senso di rotazione del motore.

void loop() 
{
    // una rotazione in una direzione
    Serial.println("Rotazione oraria");
    mioStepper.step(stepPerRotazione);
    delay(500);

    // una rotazione in una direzione
    Serial.println("Rotazione antioraria");
    mioStepper.step(-stepPerRotazione);
    delay(500);
}

Esercizi per i miei studenti

Esercizio 1
Realizzare un sistema che permetta la marcia e l’arresto del motore passo passo mediante l’uso di due pulsanti.

Esercizio 2
Realizzare un sistema che permetta la marci e l’arresto ed il controllo del senso di rotazione del motore. Usare pulsanti per il controllo della marcia e dell’arresto e dell’inversione di marcia.

Esercizio 3
Realizzare un sistema che mediante serial monitor permetta l’impostazione del numero di rotazioni e del senso di rotazione.

Esercizio 4
Realizzare un sistema che mediante tastierino esterno consenta di impostare il numero di rotazioni del sistema e il senso di rotazione del motore.
Utilizzare un display 16×2 I2C da usare per messaggi e allarmi.

Sul display dovrà essere visualizzato:

Numero di giri in tempo reale
Passi del motore
Senso di rotazione

Esercizio 5
Svolgere le stesse funzionalità dell’esercizio 4 ed aggiungere un sensore di temperatura TPM36 che superato un valore limite di temperatura di riscaldamento del motore passo passo attivi una ventola che lo raffreddi riportando la temperatura nel range di sicurezza stabilito, cessato l’allarme la ventola di raffreddamento si deve fermare.

Condividi:

Articoli correlati:

Articoli correlati: